Notify Admins about users that are about to expire (Requires a R6+ server)

Note: to make it R5+ compatible you could change the code to use @Certificate function in an evaluate statement and have it loop through all person/server documents. (Roy Holder & Bill Buchan were kind enough to remind me about the existence of that function)

Agent Information

Name: Certificate Expiration Notification
Last Modification: 24-08-2005 16:51:52
Comment: [Not Assigned]
Shared Agent: Yes
Type: LotusScript
State: Enabled
Trigger: Scheduled
Interval: On Schedule Weekly
Acts On: All new and modified documents since last run
LotusScript Code:
Option Public
Option Declare
Sub Initialize
' ==========================
' Author: Ninke Westra (woonjas@hotmail.com)
' ==========================
Dim sn As New NotesSession
Dim vw As NotesView
Dim vec As NotesViewEntryCollection
Dim dc As NotesDocument
Dim ve As NotesViewEntry
Dim Body As NotesRichTextItem
On Error Goto FR
Set vw= sn.CurrentDatabase.GetView("PeopleCertExpiration") ' <------------ This view was introduced into the nab in R6
If Not vw Is Nothing Then
Set vec= vw.GetAllEntriesByKey(7, True) '<------------------------------- notify when users are about to expire within the next 7 days
If vec.count=0 Then
Set vec=vw.GetAllEntriesByKey(1, True) ' <------------------------------ make sure users that expire today/tomorrow are included
End If
If vec.count> 0 Then
Set dc= sn.CurrentDatabase.CreateDocument
If Not dc Is Nothing Then
dc.SendTo= "LocalDomainAdmins" ' <------------------------------ Group/User name to receive the notifications
dc.Subject= "Certificate Expiration"
dc.Form= "Memo"
dc.SaveMessageOnSend= False
Set Body= dc.CreateRichTextItem("Body")
Body.AppendText "There are certificates about to expire in the Domino Directory:"
Body.AddNewline 2
Set ve=vec.GetFirstEntry
Do While Not ve Is Nothing
Body.AppendText ve.ColumnValues(4)
Body.AddTab 2
Body.AppendText "Certfier: " & ve.ColumnValues(2)
Body.AddTab 2
Body.AppendText ve.ColumnValues(1)
Body.AddNewline 1
Set ve=vec.GetNextEntry(ve)
Loop
dc.Send False
Else
Msgbox "Certificate Expiration Notification agent: Could not create message"
End If
Else
' --- no expiring certs found
End If
Else
' --- could not open view
Msgbox "Certificate Expiration Notification agent: Could not open view"
End If
EF:
Exit Sub
FR:
Msgbox "Certificate Expiration Notification agent: " & Err & " - " & Error & " ocurred in line " & Erl
Resume EF
End Sub